Broncode: eenvoudig database script
Dit script leest de gegevens uit een database en geeft die gegevens in een tabel weer.
<% Option Explicit %>
<% RESPONSE.BUFFER=TRUE %>
<%
Dim objConn, objRS, strSQL
On Error Resume Next
'// Query voor alle gegevens van alle artikelen uit de artikelen-tabel.
strSQL = "SELECT * FROM tbl_Artikelen"
'// De gegevens inlezen. De dsn (dsnnaam) maken wij voor u aan, mail beheer@nedcomp.nl.
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "dsn=dsnnaam;uid=inlognaam;pwd=wachtwoord;"
Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.Open strSQL, objConn, 3, 3
'// Is er een fout opgetreden? Dan een foutmelding weergeven.
If Err <> 0 Then
'// Redirecten naar een pagina die een foutmelding bevat.
Response.Redirect "offline.asp"
Response.Flush: Response.End
'// Controleren of de recordset gegevens bevat.
ElseIf objRS.BOF Or objRS.EOF Then
'// De recordset cq tabel is leeg, een foutmelding weergeven.
Response.Redirect "offline.asp"
Response.Flush: Response.End
End If
%>
<html>
<head>
<title>Practical Active Server Pages : database uitlezen, script 1</title>
<meta name="Description" content="Voorbeeld voor het uitlezen van een database.">
<!-- Practical ASP wordt u aangeboden door Nedcomp Hosting -->
</head>
<body bgcolor="#FFFFFF">
<table border="0" cellpadding="1">
<% '// In een loop alle gegevens opnemen in onderstaande html.
Do Until objRS.EOF %>
<tr>
<td><font face="Arial, Helvetica" size="2">recordnr <%= objRS("artikelid") %></font></td>
<td> </td>
<td><font face="Arial, Helvetica" size="2"><%= objRS("artikelnaam") %></font></td>
<td> </td>
<td align="right"><font face="Arial, Helvetica" size="2">
<%= FormatCurrency(objRS("artikelprijs")) %></font></td>
</tr>
<tr><td colspan="5"><hr width="100%" size="1" color="#669966"></td></tr>
<%
'// Volgend record.
objRS.MoveNext
Loop %>
<%
'// De objecten opruimen, deze zijn niet meer nodig.
Set objRS = Nothing
Set objConn = Nothing %>
</table>
</body>
</html>
|
Producten en diensten
Algemeen