 |
Broncode: RegExp Object, ingevoerde waarden controleren.
Dit script controleerd, aan de hand van een verificatiestring
met geldige waarden, de waarde die is ingevuld in een
tekst-veld.
<% Option Explicit %>
<%
Function VerifyString(Pattern, StringToTest)
'--------------------------------------------------------------------------------
' Pattern matching. Voorbeeld:
' VerifyString("[^A-Za-z0-9_.-]", "sup#port.nedcomp.nl")
' Het karakter # is hierin ongeldig, de functie geeft 'false'.
'--------------------------------------------------------------------------------
Dim objRegEx
On Error Resume Next
If Trim(StringToTest) = "" Then: Exit Function
'// Regexp-object maken en afbreken wanneer dit niet lukt.
Set objRegEx = New RegExp
If Err <> 0 Then: Exit Function
'// De geldige (of juist ongeldige karakters) toewijzen.
objRegEx.Pattern = Pattern
'// Controleren, het resultaat retourneren en het object opruimen.
VerifyString = Not objRegEx.Test(StringToTest)
Set objRegEx = Nothing
End Function
%>
<head>
<title>Practical Active Server Pages : RegExp Object, ingevoerde waarden controleren.</title>
<meta name="Description" content="Voorbeeld van het gebruik van het RegExp Object.">
<!-- Practical ASP wordt u aangeboden door Nedcomp Hosting -->
</head>
<body bgcolor="#ffffff">
<p>
<%
Dim sValue
'// Opvragen wat er was ingevuld in het formulierveld.
sValue = Request.Form("testveld")
'// Controleren op ongeldige tekens, 0 tot 9 en de komma zijn de enige geldige tekens.
If VerifyString("[^0-9,]", sValue) Then
Response.Write sValue & " is geldig!"
Else
Response.Write "<font color=""red"">" & sValue & " is ongeldig!!!</font>"
End If
%>
</p>
<p>
Nadat u in het onderstaande veld een tekst heeft ingevoerd en op versturen heeft<br>
geklikt zal de functie controleren of de ingevoerde tekens geldig waren.<br>
Geldige tekens: 0 tot 9 en de komma.
<!-- Formulier voor het invoeren van de waarden die gecontroleerd moeten worden. -->
<form action="<%= Request.ServerVariables("SCRIPT_NAME") %>" method="POST">
<input type="text" name="testveld" size="10">
<input type="submit" value="versturen">
</form>
</p>
</body>
</html>
|
|
Producten en diensten
Algemeen